'===========================================================
' FileCheck Macro                     By 1994/x/x  Ryn
'===========================================================
'
' ファイルは在りや無しや 関数
'          Flg = 1 の時、ファイルが在れば True を返す
'          Flg = 2 の時、ファイルが無ければ True を返す
'
Function FileCheck(FileName, Flg)
    Dim Message, Title As String
'
    Title = "エラーメッセージ"
    FileCheck = True
    On Error GoTo CheckError
        If Dir(FileName) = "" And Flg = 1 Then
            Message = "ファイルが見つかりません      ファイル名 = " & FileName
            MsgBox Message, vbExclamation, Title
            FileCheck = False
        ElseIf Dir(FileName) <> "" And Flg = 2 Then
            Message = "ファイルは既に存在しています  ファイル名 = " & FileName
            MsgBox Message, vbExclamation, Title
            FileCheck = False
        End If

Exit_Function:
        Exit Function

CheckError:                                                     ' エラー処理ルーチン
    Const ERR_PathNotFound = 76, _
          ERR_DiskNotReady = 71, _
          ERR_DeviceUnAvailable = 68

    FileCheck = False
    Select Case Err
        Case ERR_PathNotFound, ERR_DiskNotReady
            Message = "ディスクをドライブに入れて、ドアを閉じて下さい"
            If MsgBox(Message, vbExclamation + vbRetryCancel, Title) = vbRetry Then
                Resume
            Else
                Resume Exit_Function
            End If
       Case ERR_DeviceUnAvailable
            Message = "ドライブまたはパスが見つかりません   " & FileName
            MsgBox Message, vbExclamation, Title
            Resume Exit_Function
       Case Else
            Message = "予期しないエラーです！　エラー番号 " & Str(Err) & _
                ": " & Error(Err)
            MsgBox Message, vbCritical, Title
    End Select
End Function